Simulation mit Fehlern

+A -A
Autor
Beitrag
paga58
Inventar
#1 erstellt: 28. Aug 2008, 19:34
Hallo,

wenn ich diese importierten Modelle unter LTspice laufen lasse hab ich Probleme:


*LF412 LOW OFFSET, LOW DRIFT DUAL JFET INPUT OP-AMP MODEL
*
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LF412 1 2 99 50 28
*
*Features:
*Fast settling time (.01%) = 2uS
*High bandwidth = 3MHz
*High slew rate = 10V/uS
*Low offset voltage = 1mV
*Low supply current = 1.8mA
*NOTE: Model is for single device only and simulated
* supply current is 1/2 of total device current.
*
IOS 2 1 25.0P
CI1 1 0 3P
CI2 2 0 3P
R1 1 3 1E12
R2 3 2 1E12
I1 99 4 1.0M
J1 5 2 4 JX412
J2 6 7 4 JX412
R3 5 50 650
R4 6 50 650
C4 5 6 4.372P
I2 99 50 800UA
*EOS 7 1 POLY(1) 16 49 1E-3 1
BOS 7 1 v= 1E-3 + 1*v(16,49)
R8 99 49 80K
R9 49 50 80K
V2 99 8 2.13
D1 9 8 DX412
D2 10 9 DX412
V3 10 50 2.13
EH 99 98 99 49 1
G1 98 9 5 6 20E-3
R5 98 9 10MEG
VA3 9 11 0
C3 98 11 857.516P
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.305E-15
G4 98 16 3 49 1E-8
L2 98 17 144.7M
R13 17 16 1K
F6 99 50 VA7 1
F5 99 23 VA8 1
D5 21 23 DX412
VA7 99 21 0
D6 23 99 DX412
E1 99 26 99 15 1
VA8 26 27 0
R16 27 28 50
V5 28 25 0.646V
D4 25 15 DX412
V4 24 28 0.646V
D3 15 24 DX412
.ENDS LF412
.MODEL DX412 D(IS=1E-15)
.MODEL JX412 PJF(BETA=1.183E-3 VTO=-.65 IS=50E-12)
*
***
*
* AD712J SPICE Macro-model 4/92, Rev. B
* JCB/JW/PMI
*
* This version of the AD712 model simulates the worst case
* parameters of the 'J' grade. The worst case parameters
* used correspond to those in the data sheet.
*
* Revision History:
* Rev B: Convert model into ADSpice format
* Add noise generators
*
* Copyright 1990 by Analog Devices, Inc.
*
* Refer to "README.DOC" file for License Statement. Use of this model
* indicates your acceptance with the terms and provisions in the License Statement.
*
* Node assignments
* non-inverting input
* | inverting input
* | | positive supply
* | | | negative supply
* | | | | output
* | | | | |
.SUBCKT AD712J 1 2 99 50 30
*
* INPUT STAGE
*
R3 5 50 5.305
R4 6 50 5.305
CIN 1 2 5.5E-12
I1 99 4 100E-3
IOS 1 2 12.5E-12
EOS 60 1 POLY(1) 17 24 3E-3 1
EN 7 60 42 0 1
GN1 0 1 45 0 1E-6
GN2 0 2 48 0 1E-6
J1 5 2 4 JX
J2 6 7 4 JX
GB1 2 50 POLY(3) 4,2 5,2 50,2 0 1E-12 1E-12 1E-12
GB2 7 50 POLY(3) 4,7 6,7 50,7 0 1E-12 1E-12 1E-12
*
EREF 98 0 24 0 1
*
* VOLTAGE NOISE GENERATOR
*
VN1 41 0 DC 2
DN1 41 42 DEN
DN2 42 43 DEN
VN2 0 43 DC 2
*
* CURRENT NOISE GENERATOR
*
VN3 44 0 DC 2
DN3 44 45 DIN
DN4 45 46 DIN
VN4 0 46 DC 2
*
* CURRENT NOISE GENERATOR
*
VN5 47 0 DC 2
DN5 47 48 DIN
DN6 48 49 DIN
VN6 0 49 DC 2
*
* SECOND STAGE & POLE AT 32 HZ
*
R5 9 98 7.96E5
C3 9 98 6.25E-9
G1 98 9 5 6 1.88E-1
V2 99 8 2.2
V3 10 50 2.8
D1 9 8 DX
D2 10 9 DX
*
* COMMON-MODE GAIN NETWORK WITH ZERO AT 2.4kHZ
*
R11 16 17 1E6
C8 16 17 6.695E-11
R12 17 98 1
E3 16 98 POLY(2) 1 98 2 98 0 79.24 79.24
*
* POLE AT 15 MHZ
*
R13 18 98 1E3
C9 18 98 10.61E-12
G5 98 18 9 24 1E-3
*
* OUTPUT STAGE
*
R14 24 99 500E3
R15 24 50 500E3
CF 24 0 1E-6
ISY 99 50 -93.2E-3
R16 29 99 110
R17 29 50 110
L1 29 30 1E-8
G6 27 50 18 29 9.09E-3
G7 28 50 29 18 9.09E-3
G8 29 99 99 18 9.09E-3
G9 50 29 18 50 9.09E-3
V4 25 29 0.675
V5 29 26 0.675
D3 18 25 DX
D4 26 18 DX
D5 99 27 DX
D6 99 28 DX
D7 50 27 DY
D8 50 28 DY
F1 29 0 V4 1
F2 0 29 V5 1
*
* MODELS USED
*
.MODEL JX PJF(BETA=1.78E-1 VTO=-2.000 IS=75E-12 RD=0
+ RS=0 CGD=1E-12 CGS=1E-12)
.MODEL DX D(IS=1E-15 RS=0 CJO=1E-12)
.MODEL DY D(IS=1E-15 BV=50 RS=10 CJO=1E-12)
.MODEL DEN D(IS=1E-12 RS=30909 KF=2.651E-15 AF=1)
.MODEL DIN D(IS=1E-12 RS=12090 KF=0 AF=1)
.ENDS AD712J


Beim LF412 klappt Frequenzgang und Klirranalyse, Rauschen ist dubios.
Beim AD412 stimmen Frequenzgang und Rauschen, bei der Transientenanalyse mit 1k Sinus
hängt sich Spice nach der ersten Halbwelle auf.
Stimmen die Modelle nicht oder passen sie einfach nicht zu LT?

Grüße

Achim
Suche:
Das könnte Dich auch interessieren:
Brückengleichrichter und "Split Power Supply"
Spl-Mistress am 04.09.2009  –  Letzte Antwort am 13.09.2009  –  50 Beiträge
LM3886 Model Subckt
kap am 11.09.2008  –  Letzte Antwort am 14.09.2008  –  4 Beiträge
Shunt regulated power supply - Vorteile?
stopbit am 05.09.2010  –  Letzte Antwort am 11.09.2010  –  26 Beiträge
Split Power Supply? Wo bekommen?
killertiger am 29.12.2006  –  Letzte Antwort am 30.12.2006  –  6 Beiträge
Input und Output Voltage
Karkarov am 23.01.2021  –  Letzte Antwort am 23.01.2021  –  2 Beiträge
LJM-15D Power supply mit DC füttern
Junta am 31.05.2018  –  Letzte Antwort am 03.06.2018  –  7 Beiträge
Trafo; dickes Kabel = Input/Output?
mercNr am 22.05.2009  –  Letzte Antwort am 22.05.2009  –  3 Beiträge
Amp mit Single 24V Supply
Spl-Mistress am 23.12.2010  –  Letzte Antwort am 28.12.2010  –  5 Beiträge
Frage bezüglich Input Verkabelung für Stereo Amp
Keskin am 28.02.2009  –  Letzte Antwort am 28.02.2009  –  3 Beiträge
Input Bias Current
Obes am 19.12.2019  –  Letzte Antwort am 29.12.2019  –  10 Beiträge
Foren Archiv
2008

Anzeige

Aktuelle Aktion

Partner Widget schließen

  • beyerdynamic Logo
  • DALI Logo
  • SAMSUNG Logo
  • TCL Logo

Forumsstatistik Widget schließen

  • Registrierte Mitglieder925.513 ( Heute: 2 )
  • Neuestes Mitglied*plaut*
  • Gesamtzahl an Themen1.550.299
  • Gesamtzahl an Beiträgen21.521.382

Hersteller in diesem Thread Widget schließen