Neu, Fragen zu Elrog ER300B & AÜ

Moin Alex,

Und willkommen.
Diese Fragestellung schreit geradezu nach einer Antwort meinerseits...

Momentan tendiere ich zum S-11 mit 5K. Ein 8K würde theoretisch den DF vergrößern und den Klirr verringern... Hat jemand zufällig so eine Kombination schon mal getestet?

Nun, den S-11 hatte ich noch nicht in der Mache, wohl aber den S-5. 8K:8...und diesen auch explizit für die ER300B beschafft.
Allerdings sei zu erwähnen, dass man mit "normalen" Arbeitsbedingungen für 300B (so wie auch in Deiner Schaltung) den S-9 (3.3k:8) auch für die ER300B nutzen sollte. Bestes Verhältnis von Klirr zu Dämpfung zu Leistung. Die ER300B ist mit ihrer thorierten Kathode jedoch ein ganz anderes Kaliber. Richtig gut geht das erst mit richtig viel Anodenspannung ab...so 500V...das metzelt alle anderen 300B-Derivate dahin, die ER fühlt sich dann erst richtig wohl. Und dann passt auch der S-5 (der eigentlich für eine 845 entwickelt wurde) super. Normale 300B-Arbeitspunkte sind für eine ER300B eher so was wie 5,7l V8 im Leerlauf...es brodelt "untenrum" (was Oxid-Kathoden-300B gar nicht können) und das Drehmoment lässt die Räder durchdrehen...Wenn man aber "richtig Gas geben" will, dann höhere Anodenspannungen und hohe Impedanzen... Allerdings ist man dann auf diese Teile (ER300B) angewiesen, da keine andere 300B solches Tun über längere Zeit schadlos hinnimmt.
Dein Treiber-Konzept gefällt mir nicht so wirklich...
Eine (ER)300B kann man immer mit einer einstufigen Sache treiben, sei es nun eine Penthode mit RC-Koppelung oder eine Triode, nebst Anodendrossel, in LC-Koppelung. Deine Treiberei ist zwar sehr klirrarm, aber will man sowas wirklich immer? (Stichwort Vorwärtskompensation.) Und das geht auch immer ohne Eingangsübertrager. Mein (Design-)Ziel ist ein Phasenfehler von <+-20° von 20Hz bis 20kHz, über die gesamte Kette, da kann also auch noch ein Phono-Pre drin sein..."Untenrum" hast Du davon schon sehr viel verbraucht (und der LL7903 ist da noch gar nicht drin enthalten...)

Gruß. Matthias

Rolf_Meyer (Beitrag #2) schrieb:

Moin Alex, ... Und dann passt auch der S-5 (der eigentlich für eine 845 entwickelt wurde) super. Normale 300B-Arbeitspunkte sind für eine ER300B eher so was wie 5,7l V8 im Leerlauf...es brodelt "untenrum" (was Oxid-Kathoden-300B gar nicht können) und das Drehmoment lässt die Räder durchdrehen.... Allerdings ist man dann auf diese Teile (ER300B) angewiesen, da keine andere 300B solches Tun über längere Zeit schadlos hinnimmt. )

Hallo Matthias,

vielen Dank zu deinen Erkenntnissen Die Sache mit den dem S-5 AÜ klingt doch nicht verkehrt.So wie ich das hier im Forum sehe, bist Du bei der Herstellung der ER Röhren nicht ganz unbeteiligt?
Bei den 500V: meinst Du Ua auf Massebezug, oder Ua zur Kathode? Wie schauts denn da mit der Lebansdauer aus?

Rolf_Meyer (Beitrag #2) schrieb:

Eine (ER)300B kann man immer mit einer einstufigen Sache treiben, sei es nun eine Penthode mit RC-Koppelung oder eine Triode, nebst Anodendrossel, in LC-Koppelung. Deine Treiberei ist zwar sehr klirrarm, aber will man sowas wirklich immer? (Stichwort Vorwärtskompensation.) Und das geht auch immer ohne Eingangsübertrager. Mein (Design-)Ziel ist ein Phasenfehler von <+-20° von 20Hz bis 20kHz, über die gesamte Kette, da kann also auch noch ein Phono-Pre drin sein..."Untenrum" hast Du davon schon sehr viel verbraucht (und der LL7903 ist da noch gar nicht drin enthalten...)

Naja die Phasensauerei ist in der Tat ein wenig zu viel .
Interessant wäre als Alternative mMn der 6SN7-Treiber mit Anodendrossel nach "Reinhöfer-Art". Das ist auch etwas mehr Hubraum drinne.


Klirrt ähnlich wie mein DHTs-Treiber aber die Phasentreue ist eindeutig besser:


Allerdings wird es für die 6sn7 schwierig werden, der 10 oder 801( Wolframheizer) in Puncto Auflösung das Wasser zu reichen.

PS: Hättest Du evtl. ein Spice-Modell zur ER300b?

Gruß Alex

Moin Alex,

Bei den 500V: meinst Du Ua auf Massebezug, oder Ua zur Kathode?

Ich meine tatsächlich eine Ua von 500V, also zwischen Heizungsfaden-Minus und Anode...Das ergibt eine Betriebsspannung von >600V bei automatischer Gittervorspannung (Kathodenwiderstand+Brückenkondensator)

Wie schauts denn da mit der Lebansdauer aus?

Keine Änderung, solange man Na nicht überschreitet...40W...Bedeutet also einen Ruhestrom von max. 75-80mA bei 500V Ua.

Interessant wäre als Alternative mMn der 6SN7-Treiber mit Anodendrossel nach "Reinhöfer-Art".

In der Tat, eine ganz außergewöhnliche Schalte...und mit der gelieferten Anodendrossel tut sie genau das, was sie soll. Klirrarm und relativ niederohmig treiben...Mit leicht geänderten Kathodenwiderständen laufen diese Teile in meinen Messverstärkern und müssen sogar 845 an die Leistungsgrenze treiben...aber 300Vpp sind für diese Schalte gar kein Problem. Für eine (ER)300B ist sie jedoch zu klirrarm . Die 845 erzeugt so gut wie gar keinen Klirr, also muss da auch nix vorwärtskompensiert werden...die (ER)300B schon...Etwas Klirr2 in der Vorstufe/Treiberei hebt (unter geringer Erhöhung des Klirr3) den Klirr2 der Endstufe auf...K3 entsteht bei einer ER300B so gut wie keiner...deshalb kann man sich solches Vorgehen leisten.

Allerdings wird es für die 6sn7 schwierig werden, der 10 oder 801( Wolframheizer) in Puncto Auflösung das Wasser zu reichen.

Auch richtig...Deswegen habe ich mir auch schon Treiberröhren selbst erdacht...denn,weder die 10Y noch die 801 passt perfekt zur ER300B.
Da Du ja in Norddeutschland bist, sollten wir zu diesem Thema dringend mal persönlich diskutieren (Das ist eine Einladung )
Hier das gewünschte Modell:


* ER300B_fil.inc
* This file creates a composite ER300B Valve. It models
* 1. the 300B "plate characteristics"
* 2. parasitic capacitances
* 3. Filament voltage-vs-current characteristics
* 4. emission change with heating power change
* 5. Effect of anode current on heating
* 6. Filament inrush current and heating time (thermal time constant)
* 7. Current distributed over the valve modelled in 5 sections
* 8. Distributed grid currrent based on each of the 5 sections of valve

* Use DHTriode.asy for the symbol


.SUBCKT ER300B 1 2 3 4 ; P G F- F+ version3 Stephie 5-1-2015 This version adds in the effect of space charge temperature limitation
.param MU=3.4
.param RGI=23k
.param EX=1.532
.param EX1=-.372
.param ex2=.1022584
.param kg1=24330 ; note another change in transconductance parameter to account for temp limit effects
.param kp=57.3
.param kvb=334.16
.param vct=-0.66 ; changed to account for temp limit on emission 5-1-2015

.param rh=.70852 ; full segment heating hot resistance
.param rc=.12 ; full segment cold resistance
.param rh1=.35426 ; half segment heating hot resistance
.param rc1=.06 ; half segment cold resistance
.param ch=.6 ; heating time constant capacitance
.param hf=.5 ; heating multiplier factor. Typically just .5
.param hex=1.31 ; exponent of heating coefficient for anode current change

.param emo=66.5 ; effectively the offset voltage before starting to limit the current via the internal nodes (7-11)
.param dio=400 ; build out resistance from internal voltage sources to the clamps on V(7)-V(11)
.param is=5.1e-3 ; DEM diode model saturation current - these params create a soft clamp in diodes D6-D10
.param rs=.9 ; DEM diode model series resistance
.param N=160 ; DEM diode model N parameter (softness)

.param ccg= 10p
.param ccp= 5p
.param cgp=15p

* .ic v(tf1)=0 ; initially, no charge on capacitors (cold)
* .ic v(tf2)=0
* .ic v(tf3)=0
* .ic v(tf4)=0
* .ic v(tf5)=0
* .ic v(tf6)=0

*heater/filament
B1 k1 k2 I=v(K1,K2)/({rh1}*v(tf1)+{rc1})
B2 k2 k3 I=v(K2,K3)/({rh}*v(tf2)+{rc})
B3 k3 k4 I=v(K3,K4)/({rh}*v(tf3)+{rc})
B4 k4 k5 I=v(K4,K5)/({rh}*v(tf4)+{rc})
B5 k5 k6 I=v(K5,K6)/({rh}*v(tf5)+{rc})
B6 k6 k7 I=v(K6,K7)/({rh1}*v(tf6)+{rc1})
R8 3 k1 1µ
R1 k7 4 1µ
*heating power and time constant - used in anode current and in equivalent heater/filament resistance
C1 0 tf1 {ch}
R2 P001 tf1 1
B13 P001 0 V=pwrs(v(k1,k2)*v(k1,k2)*4,.25)
C2 0 tf2 {ch}
R3 P002 tf2 1
B14 P002 0 V=pwrs(v(k2,k3)*v(k2,k3),.25)
C3 0 tf3 {ch}
R4 P003 tf3 1
B19 P003 0 V=pwrs(v(k3,k4)*v(k3,k4),.25)
C4 0 tf4 {ch}
R5 P004 tf4 1
B20 P004 0 V=pwrs(v(k4,k5)*v(k4,k5),.25)
C5 0 tf5 {ch}
R6 P005 tf5 1
B21 P005 0 V=pwrs(v(k5,k6)*v(k5,k6),.25)
C6 0 tf6 {ch}
R7 P006 tf6 1
B22 P006 0 V=pwrs(v(k6,k7)*v(k6,k7)*4,.25)
*anti float resistors
R9 K2 k1 1e9
R10 K3 K2 1e9
R11 K4 K3 1e9
R12 K5 K4 1e9
R13 K6 K5 1e9

* emission limit due to filament temperature addition
R1a 7 7a {dio} ; add the build out to the internal nodes
R2a 8 8a {dio}
R3a 9 9a {dio}
R4a 10 10a {dio}
R5a 11 11a {dio}
D6a 7 em Dem ; soft diode clamp to the limit determined by temperature of the filament
D7a 8 em Dem
D8a 9 em Dem
D9a 10 em Dem
D10a 11 em Dem
B1a em 0 V={emo}*pwrs(v(tf),6) ; the exponent might be a parameter, but 6th power models the data rather well. This voltage determines the overall current limit
B3a tf 0 V=(V(tf1)+V(tf2)+V(tf3)+V(tf4)+V(tf5)+V(tf6))/6 ; composite heat index. This normally is unity at nominal heating power.

* "normal" plate characteristics modelling, composite tube broken into 5 segments
B7 7a 0 V=V(1,k2)/{KP}*LOG(1+EXP({KP}*(1/{MU}+(V(2,k2)+{VCT})/SQRT({KVB}+V(1,k2)*V(1,k2))))) ; note output node changed to add build out resistors
B15 8a 0 V=V(1,k3)/{KP}*LOG(1+EXP({KP}*(1/{MU}+(V(2,k3)+{VCT})/SQRT({KVB}+V(1,k3)*V(1,k3)))))
B16 9a 0 V=V(1,k4)/{KP}*LOG(1+EXP({KP}*(1/{MU}+(V(2,k4)+{VCT})/SQRT({KVB}+V(1,k4)*V(1,k4)))))
B17 10a 0 V=V(1,k5)/{KP}*LOG(1+EXP({KP}*(1/{MU}+(V(2,k5)+{VCT})/SQRT({KVB}+V(1,k5)*V(1,k5)))))
B18 11a 0 V=V(1,k6)/{KP}*LOG(1+EXP({KP}*(1/{MU}+(V(2,k6)+{VCT})/SQRT({KVB}+V(1,k6)*V(1,k6)))))
* internal node has heating power added into it fo model emission change "pwrs({hf}*(v(tfx)+v(tfy)),{hex}))"
B8 1 k2 I=(PWR(V(7),0.00001*{EX2}*V(1,k2)*V(1,k2)+0.001*{EX1}*V(1,k2)+{EX})+PWRS(V(7),0.00001*{EX2}*V(1,k2)*V(1,k2)+0.001*{EX1}*V(1,k2)+{EX}))/({KG1}/pwrs({hf}*(v(tf1)+v(tf2)),{hex}))
B9 1 k3 I=(PWR(V(8),0.00001*{EX2}*V(1,k3)*V(1,k3)+0.001*{EX1}*V(1,k3)+{EX})+PWRS(V(8),0.00001*{EX2}*V(1,k3)*V(1,k3)+0.001*{EX1}*V(1,k3)+{EX}))/({KG1}/pwrs({hf}*(v(tf2)+v(tf3)),{hex}))
B10 1 k4 I=(PWR(V(9),0.00001*{EX2}*V(1,k4)*V(1,k4)+0.001*{EX1}*V(1,k4)+{EX})+PWRS(V(9),0.00001*{EX2}*V(1,k4)*V(1,k4)+0.001*{EX1}*V(1,k4)+{EX}))/({KG1}/pwrs({hf}*(v(tf3)+v(tf4)),{hex}))
B11 1 k5 I=(PWR(V(10),0.00001*{EX2}*V(1,k5)*V(1,k5)+0.001*{EX1}*V(1,k5)+{EX})+PWRS(V(10),0.00001*{EX2}*V(1,k5)*V(1,k5)+0.001*{EX1}*V(1,k5)+{EX}))/({KG1}/pwrs({hf}*(v(tf4)+v(tf5)),{hex}))
B12 1 k6 I=(PWR(V(11),0.00001*{EX2}*V(1,k6)*V(1,k6)+0.001*{EX1}*V(1,k6)+{EX})+PWRS(V(11),0.00001*{EX2}*V(1,k6)*V(1,k6)+0.001*{EX1}*V(1,k6)+{EX}))/({KG1}/pwrs({hf}*(v(tf5)+v(tf6)),{hex}))

* grid current
D1 2 k2 DX
D2 2 k3 DX
D3 2 k4 DX
D4 2 k5 DX
D5 2 k6 DX

* interelectrode capacitance
C7 2 3 {ccg}
C8 1 3 {ccp}
C9 1 2 {cgp}
.MODEL DX D(IS=200p RS={rgi} CJO=2PF TT=1N) ; note that series resistance is embedded into the diode model
.MODEL Dem D(is={is} N={n} Rs={rs}) ; soft diode used as a clamp to temperature limit emission
.ENDS



Da hat der Steve Bench maßgeblichen Anteil...neben dem Bernd aus dem Nachbar-Forum...Denn irgendwie glaube ich, dass Du da auch (unter anderem Nick) unterwegs bist...

Als Treiber würde ich eine einstufige Geschichte mit C3g in Triode (mit der Reinhöfer 600H Anodendrossel) empfehlen...(Jedenfalls solange die passenden Treiberröhren nicht offiziell verfügbar sind )

Viel Spaß beim Simulieren...das Modell ist wirklich sehr genau...man kann sogar Restwelligkeiten in der Heizspannung mitsimulieren!

Gruß, Matthias

Rolf_Meyer (Beitrag #4) schrieb:

Moin Alex, Keine Änderung, solange man Na nicht überschreitet...40W...Bedeutet also einen Ruhestrom von max. 75-80mA bei 500V Ua. . Die 845 erzeugt so gut wie gar keinen Klirr, also muss da auch nix vorwärtskompensiert werden...die (ER)300B schon...Etwas Klirr2 in der Vorstufe/Treiberei hebt (unter geringer Erhöhung des Klirr3) den Klirr2 der Endstufe auf...K3 entsteht bei einer ER300B so gut wie keiner..

hallo,

Merci, das sind doch mal nützliche Infos.

Rolf_Meyer (Beitrag #4) schrieb:

Hier das gewünschte Modell: Da hat der Steve Bench maßgeblichen Anteil...neben dem Bernd aus dem Nachbar-Forum...Denn irgendwie glaube ich, dass Du da auch (unter anderem Nick) unterwegs bist...

Danke dafür!!l!!

Rolf_Meyer (Beitrag #4) schrieb:

Da Du ja in Norddeutschland bist, sollten wir zu diesem Thema dringend mal persönlich diskutieren (Das ist eine Einladung )

ich komme auf jedenfall darauf zurück

Rolf_Meyer (Beitrag #4) schrieb:

Als Treiber würde ich eine einstufige Geschichte mit C3g in Triode (mit der Reinhöfer 600H Anodendrossel) empfehlen..

Ja die "Blechdildo-Pentode" wäre sicherlich eine Überlegung Wert.( aber nur nackisch

Gruß Alex